// !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
// ! This script is provided "as is" by Applied Maths.              !
// ! You are free to use and modify this script for your own needs. !
// ! Redistribution or reproduction of the script is prohibited.    !
// ! DISCLAIMER:                                                    !
// ! Improper use of scripts may corrupt your database.             !
// ! Running this script is entirely at your own responsibility.    !
// ! Applied Maths accepts no lialibility for any consequences      !
// ! resulting from its use.                                        !
// !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

//$DISPLAY_COMPWIN

DIALOG dlg;
string expername,str_minsim,str_minct;
float minsim,simil,signif;
integer subct,collapsed,cutoff,minct,clustercount;
integer ok,ok2;
BRANCH root,bra,bra2;

if not(CmpIsPresent) then CmpAttach;
if not(CmpIsPresent) then {
   message("Unable to attach a comparison to this script");
   stop;
}

expername=CluGetCurrent;
ok=CluGetRoot(expername,root);
if (expername="") or (not(ok)) then {
   message("There is currently no clustering displayed");
   stop;
}

str_minsim=TempRecall("clu_cutoff_threshold_minsim");
str_minct=TempRecall("clu_cutoff_threshold_minct");
if str_minsim="" then str_minsim="100";
if str_minct="" then str_minct="1";

DlgAddText(dlg,"Cut off clusters below ",15,15,110,15);
DlgAddEdit(dlg,str_minsim,135,15,50,20);
DlgAddText(dlg,"% similarity",190,15,70,15);

DlgAddText(dlg,"Clusters must have at least",15,50,140,15);
DlgAddEdit(dlg,str_minct,160,50,40,20);
DlgAddText(dlg,"members",210,50,50,15);


if not(DlgShow(dlg,"Cut off clusters",380,140)) then stop;

TempStore("clu_cutoff_threshold_minsim",str_minsim);
TempStore("clu_cutoff_threshold_minct",str_minct);


minsim=val(str_minsim);
minct=val(str_minct);

setbusy("Visiting all clusters...");
ok=CluEnumStart(root,bra);
while ok do {
   CluGetInfo(bra,simil,signif,subct,collapsed,cutoff);
   cutoff=(simil<minsim);
   if subct<minct then cutoff=1;
   CluCutoff(bra,cutoff);
   if cutoff=0 then {
      clustercount=clustercount+1;
      ok2=CluEnumStart(bra,bra2);
      while ok2 do {
         CluCutoff(bra2,0);
         ok2=CluEnumNext(bra2);
      }
      CluEnumSkip(bra);
   }
   ok=CluEnumNext(bra);
}
setbusy("");
message("Number of clusters: "+str(clustercount,0,0));